// Persistence of Vision Ray Tracer Scene Description File
// File: cloudsA.pov
// Vers: 3.5
// Desc: "fake" clouds using a simple bump mapping technique 
//       for lightsourcing a cloud pigment.
// Date: March 23, 2002
// Auth: Abe Madey (bullfrog@taconic.net)

camera {
  location <0,0,-1>     
  direction z
  right x*image_width/image_height            
  up y               
} 

//-------------------------------
//        controls
#declare sky_color= <0.11, 0.13, 0.59>; //blue sky
#declare c_bright = <0.99, 0.96, 0.88>; //illuminated color of clouds
#declare c_shade  = <0.62, 0.60, 0.70>; //shadow color of clouds   

#declare cld_s  = .2;//.50; //cloud scale  
#declare cld_ts = .5; //cloud turbulence scale  
#declare cld_t  = .3; //cloud turbulence
#declare cld_c  = .40; //cloud cover
#declare cld_e  = .05; //fuzzieness of cloud edges
#declare lt_vec = x*.025; //illumination vector(light direction) and "amount" of illumination 
#declare cld_is = .08; //softness of illumination
//-------------------------------

#declare cloud_shading=texture{
 pigment{
  bozo 
  scale cld_ts warp{turbulence cld_t lambda 2.8} scale 1/cld_ts 
  scale cld_s
  color_map{
   [0 color c_shade*.55]
   [cld_c-cld_is color c_shade]
   [cld_c  color c_bright]
  }
 }
 finish{ambient 1 diffuse 0}
}

#declare cloud_mask=texture{
 pigment{
  bozo
  scale cld_ts warp{turbulence cld_t lambda 2.8} scale 1/cld_ts 
  scale cld_s
  color_map{
   [cld_c-cld_e*.5 color sky_color transmit 1]
   [cld_c+cld_e*.5 color sky_color transmit 0]
  }
 }
 finish{ambient 1 diffuse 0}
}

#declare clouds=
 texture{cloud_shading}
 texture{cloud_mask translate lt_vec} 
                       
plane{
  -z, 0
  texture{clouds}
}