// Persistence of Vision Ray Tracer Scene Description File
// File: sky_sphere_map.pov
// Vers: 3.5
// Desc:This file was to illustrate the difference between a linear y gradient applied to
// a hemisphere and a sine modiefied gradient (i.e. latitudinal). The red lines mark the
// 25%, 50% and 75% points in the gradient.
// Date:Feb. 5, 2002
// Auth:Abe Madey (bullfrog@taconic.net) 

camera{
  location <0, 1.5, -20>
  direction z  
  look_at 0
  angle 12
}         

light_source{<100,100,-100> rgb 1 shadowless}
light_source{y*1000 rgb <.5, .5, .5> shadowless} 

background{color rgb 1}

#declare Hemisphere =
difference{
sphere{0, 1}
plane{y,0} 
}

#declare linear_texA = 
texture{
 pigment{
   gradient y
   color_map{
   [0.0 rgb .7                          transmit .6]
   [0.2 rgb <0.69922, 0.79297, 0.99609> transmit .6]
   [1.0 blue .6                         transmit .6]
   }
 }  
}
#declare linear_texB =
texture{
 pigment{
  gradient y
  color_map{
   [.25 rgbt 1]
   [.25 red 1]
   [.27 rgbt 1]
   [.50 rgbt 1]
   [.50 red 1]
   [.52 rgbt 1]
   [.75 rgbt 1]
   [.75 red 1]
   [.77 rgbt 1]
  }
 } 
}


#declare sine_texA = 
texture{
 pigment{
   gradient y
   color_map{
   [sin(0.0*.5*pi) rgb .7                          transmit .6]
   [sin(0.2*.5*pi) rgb <0.69922, 0.79297, 0.99609> transmit .6]
   [sin(1.0*.5*pi) blue .6                         transmit .6]}
 }  
} 

#declare sine_texB =
texture{
 pigment{
  gradient y
  color_map{
   [sin(.25*.5*pi) rgbt 1]
   [sin(.25*.5*pi) red 1]
   [sin(.27*.5*pi) rgbt 1]
   [sin(.50*.5*pi) rgbt 1]
   [sin(.50*.5*pi) red 1]
   [sin(.52*.5*pi) rgbt 1]
   [sin(.75*.5*pi) rgbt 1]
   [sin(.75*.5*pi) red 1]
   [sin(.77*.5*pi) rgbt 1]
  }
  
 } 
}


object{Hemisphere texture{linear_texA} texture{linear_texB} translate -x*1.05}
text { ttf "arial.ttf" "linear gradient" .1, 0 pigment{color red 1} scale .25 translate<-1.85, -.3, 0>}
object{Hemisphere texture{sine_texA}   texture{sine_texB} translate  x*1.05} 
text { ttf "arial.ttf" "sine gradient" .1, 0 pigment{color red 1} scale .25 translate<.3, -.3, 0>}